version 10.0
capture log close
log using chap03, replace
use food

* estimate regression

reg food_exp income

* compute t-critical value

scalar tc975 = invttail(38,.025)
di "t critical value 97.5 percentile = "  tc975

* calculating 95% interval estimate

scalar ub2 = _b[income] + tc975*_se[income]
scalar lb2 = _b[income] - tc975*_se[income]
di "beta 2 95% interval estimate is " lb2 " , " ub2

* examples of computing t-critical values

di "t(30) 95th percentile = " invttail(30,.05)
di "t(20) 95th percentile = " invttail(20,.05)
di "t(20) 5th percentile  = " invttail(20,.95)
di "t(30) 97.5th percentile = " invttail(30,.025)
di "t(30) 2.5th percentile  = " invttail(30,.975)

* right tail test ho:beta2 = 0

scalar tstat0 = _b[income]/_se[income]
di "t statistic for Ho: beta2=0 = " tstat0
di "t(38) 95th percentile = " invttail(38,.05)
lincom income

* right tail test ho:beta2 = 5.5

scalar tstat1 = (_b[income]-5.5)/_se[income]
di "t-statistic for Ho: beta2 = 5.5 = " tstat1
di "t(38) 99th percentile = " invttail(38,.01)
lincom income-5.5

* left tail test ho:beta2 = 15

scalar tstat2 = (_b[income]-15)/_se[income]
di "t-statistic for Ho: beta2 = 15 = " tstat2
di "t(38) 5th percentile = " invttail(38,.95)
lincom income-15

* two tail test ho:beta2 = 7.5

scalar tstat3 = (_b[income]-7.5)/_se[income]
di "t-statistic for Ho: beta2 = 7.5 = " tstat3
di "t(38) 97.5th percentile = " invttail(38,.025)
lincom income-7.5

* two tail test ho:beta1 = 0

lincom _cons

* p value for right tail test

di "p value for right tail test ho:beta2 = 5.5 is " ttail(38,tstat1)

* p value for left tail test

scalar tstat2 = (_b[income]-15)/_se[income]
di "p value for left tail test ho:beta2 = 15 is " 1-ttail(38,tstat2)

* p value for a two tail test

scalar phalf = ttail(38,abs(tstat3))
scalar p3 = 2*phalf
di "p value for two tail test ho:beta2 = 7.5 is " p3
di "p value for ho:beta2 = 7.5 is " 2*ttail(38,abs(tstat3))

log close
translate chap03.smcl chap03.txt, replace