version 10.0
capture log close
log using appx_b, replace

* binomial probabilities
scalar prob1 = binomial(13,7,.7)
di "probability <= binomial(13,7,.7) " prob1
scalar prob2 = 1 - binomial(13,7,.7)
di "probability > binomial(13,7,.7) " prob2

* compute normal probabilities
scalar prob = normal((6-3)/3) - normal((4-3)/3)
di "probability 3<=N(3,9)<=6 " prob

* plot normal
set obs 101
gen x = -5 + (_n-1)/10
gen normal_pdf = normalden(x)
twoway connected normal_pdf x, xline(1.33 1.645)
more
twoway (connected normal_pdf x, msymbol(none)), xline(1.33 1.645) xlabel(-5(1)5)
more

scalar n_95 = invnormal(.95)
di "95th percentile of standard normal " n_95
scalar n_tail = normal(1.33)
di "lower tail probability normal < 1.33 " n_tail

* plot t(3)
generate t3_pdf = tden(3,x)
twoway (connected  t3_pdf x) (connected normal_pdf x)
more
twoway (connected t3_pdf x, msymbol(none))(connected normal_pdf x, msize(small) msymbol(circle)),xlabel(-5(1)5)
more
twoway (connected  t3_pdf x, msymbol(none) ), xline(1.33 2.35) xlabel(-5(1)5)
more

* t probabilities
scalar t3_95 = invttail(3,.05)
di "95th percentile of t(3) " t3_95
di "5th percentile of t(3) " invttail(3,.95)

scalar t_tail = ttail(3,1.33)
di "upper tail probability t(3) > 1.33 " t_tail
di "lower tail probability t(3) < 1.33 " 1 - ttail(3,1.33)

* Plot F-density
gen xf = _n/16.67
generate f_pdf = Fden(8,20,xf)
twoway (connected f_pdf xf, msymbol(none) ), xlabel(0(.5)7) xline(2.447 3.0)
more

* F probabilities
scalar f_95 = invFtail(8,20,.05)
di "95th percentile of F(8,20) " f_95
scalar f_tail = Ftail(8,20,3.0)
di "upper tail probability F(8,20) > 3.0 " f_tail
di "upper tail probability F(8,20) > 3.0 " 1-F(8,20,3.0)

* Chi square density
clear
set obs 101
gen xc = _n/5
scalar df = 7
gen chi2_pdf =(1/(2^(df/2))) *(1/exp(lngamma(df/2)))*xc^(df/2 - 1)*exp(-xc/2)
twoway (connected chi2_pdf x, msymbol(none)), xlabel(0(2)21) xline(14.067 15)
more

* chi-square probabilities
scalar chi2_95 = invchi2tail(df,.05)
di "95th percentile of chi2(7) " chi2_95
scalar chi2_tail = 1 - chi2(df,15)
di "upper tail probability chi2(7) > 15 " chi2_tail

log close
translate appx_b.smcl appx_b.txt